LSL: UpdateLinkSitTarget()

// Sets/Updates the sit target moving the avatar on it if necessary.
// Written by Strife Onizuka, size adjustment provided by Talarus Luan
// http://wiki.secondlife.com/wiki/User:Strife_Onizuka/UpdateLinkSitTarget
UpdateLinkSitTarget(integer link, vector pos, rotation rot) {
    //Using this while the object is moving may give unpredictable results.
    llLinkSitTarget(link, pos, rot);
    key user = llAvatarOnLinkSitTarget(link);
    if (user) {
        // If there is a user seated on the sit target update their position
        vector size = llGetAgentSize(user);
        if (size) {
            //This tests to make sure the user really exists.
            integer linkNum = llGetNumberOfPrims();
            do {
                if (user == llGetLinkKey(linkNum)) {
                    // Just checking to make sure the index is valid.
                    // We need to make the position and rotation local to the current prim
                    list local;
                    if (llGetLinkKey(link) != llGetLinkKey(1))
                        // Need the local rot if it's not the root.
                        local = llGetLinkPrimitiveParams(link, [PRIM_POS_LOCAL, PRIM_ROT_LOCAL]);
                    float fAdjust = ((((0.008906 * size.z) + -0.049831) * size.z) + 0.088967) * size.z;
                    llSetLinkPrimitiveParamsFast(linkNum, [
                        PRIM_POS_LOCAL, ((pos + <0.0,0.0,0.4> - (llRot2Up(rot) * fAdjust)) * llList2Rot(local, 1)) + llList2Vector(local, 0),
                        PRIM_ROT_LOCAL, rot * llList2Rot(local, 1)
                    ]);
                    jump end; //cheaper but a tad slower then return
                }
            } while (--linkNum);
        } else {
            //It is rare that the sit target will bork but it does happen, this can help to fix it.
            llUnSit(user);
        }
    }
    @end;
}